//------------------------------------------------------------------------
// 简称: TurtleTrader
// 名称: 海龟交易系统
// 类别: 公式应用
// 类型: 内建应用
//------------------------------------------------------------------------
Params
    Numeric nEntries(3);                    // 最大建仓次数
    Numeric RiskRatio(1);                    // % Risk Per N ( 0 - 100)
    Numeric ATRLength(20);                    // 平均波动周期 ATR Length
    Numeric boLength(20);                    // 短周期 BreakOut Length
    Numeric fsLength(55);                    // 长周期 FailSafe Length
    Numeric teLength(10);                    // 离市周期 Trailing Exit Length
    Bool LastProfitableTradeFilter(True);    // 使用入市过滤条件
Vars
    Numeric MinPoint;                        // 最小变动单位
    Series<Numeric> AvgTR;                    // ATR
    Numeric N;                                // N 值
     Numeric TotalEquity;                    // 按最新收盘价计算出的总资产
    Numeric TurtleUnits;                    // 交易单位
    Series<Numeric> DonchianHi;                // 唐奇安通道上轨，延后1个Bar
    Series<Numeric> DonchianLo;                // 唐奇安通道下轨，延后1个Bar
    Series<Numeric> fsDonchianHi;            // 唐奇安通道上轨，延后1个Bar，长周期
    Series<Numeric> fsDonchianLo;            // 唐奇安通道下轨，延后1个Bar，长周期
    Numeric ExitHighestPrice;                // 离市时判断需要的N周期最高价
    Numeric ExitLowestPrice;                // 离市时判断需要的N周期最低价
    Numeric myEntryPrice;                    // 开仓价格
    Numeric myExitPrice;                    // 平仓价格
    Bool SendOrderThisBar(False);            // 当前Bar有过交易
    Series<Numeric> preEntryPrice(0);        // 前一次开仓的价格 注意类型
    Series<Bool> PreBreakoutFailure(false);    // 前一次突破是否失败
Events
    OnBar(ArrayRef<Integer> indexs)
    {
        
        If(BarStatus == 0)//第一根bar上
        {
            preEntryPrice = InvalidNumeric;//前一次开仓价格是无效值
            PreBreakoutFailure = false;        //前一次突破设置未失败
        }
        MinPoint = MinMove*PriceScale;//最小跳数
        AvgTR = XAverage(TrueRange,ATRLength);//计算ATR
        N = AvgTR[1];                    //n值确定为上一根bar的值
        TotalEquity = Portfolio_CurrentCapital() + Portfolio_UsedMargin();//总权益
        TurtleUnits = (TotalEquity*RiskRatio/100) /(N * ContractUnit()*BigPointValue());//海归单位
        TurtleUnits = IntPart(TurtleUnits); // 对小数取整
        DonchianHi = HighestFC(High[1],boLength);//上轨bo 20
        DonchianLo = LowestFC(Low[1],boLength);    //下轨bo  20
        fsDonchianHi = HighestFC(High[1],fsLength);//快速上轨55
        fsDonchianLo = LowestFC(Low[1],fsLength);//快速下轨55
        ExitLowestPrice = LowestFC(Low[1],teLength);//平仓下轨10
        ExitHighestPrice = HighestFC(High[1],teLength);//平仓上轨10
        Commentary("N="+Text(N));
        Commentary("preEntryPrice="+Text(preEntryPrice));
        Commentary("PreBreakoutFailure="+IIFString(PreBreakoutFailure,"True","False"));
        // 当不使用过滤条件，或者使用过滤条件并且条件为PreBreakoutFailure为True进行后续操作
        If(MarketPosition == 0 && ((!LastProfitableTradeFilter) Or (PreBreakoutFailure)))
        {
            // 突破开仓
            If(High > DonchianHi && TurtleUnits >= 1)
            {
                // 开仓价格取突破上轨+一个价位和最高价之间的较小值，这样能更接近真实情况，并能尽量保证成交
                myEntryPrice = min(high,DonchianHi + MinPoint);
                myEntryPrice = IIF(myEntryPrice < Open, Open,myEntryPrice); // 大跳空的时候用开盘价代替
                preEntryPrice = myEntryPrice;
                Buy(TurtleUnits,myEntryPrice);
                SendOrderThisBar = True;
                PreBreakoutFailure = False;
            }
            If(Low < DonchianLo && TurtleUnits >= 1)
            {
                // 开仓价格取突破下轨-一个价位和最低价之间的较大值，这样能更接近真实情况，并能尽量保证成交
                myEntryPrice = max(low,DonchianLo - MinPoint);
                myEntryPrice = IIF(myEntryPrice > Open, Open,myEntryPrice); // 大跳空的时候用开盘价代替
                preEntryPrice = myEntryPrice;
                SendOrderThisBar = True;
                SellShort(TurtleUnits,myEntryPrice);
                SendOrderThisBar = True;
                PreBreakoutFailure = False;
            }
        }
        // 长周期突破开仓 Failsafe Breakout point
        If(MarketPosition == 0)
        {
            Commentary("fsDonchianHi="+Text(fsDonchianHi));
            If(High > fsDonchianHi && TurtleUnits >= 1)
            {
                // 开仓价格取突破上轨+一个价位和最高价之间的较小值，这样能更接近真实情况，并能尽量保证成交
                myEntryPrice = min(high,fsDonchianHi + MinPoint);
                myEntryPrice = IIF(myEntryPrice < Open, Open,myEntryPrice); // 大跳空的时候用开盘价代替
                preEntryPrice = myEntryPrice;
                Buy(TurtleUnits,myEntryPrice);
                SendOrderThisBar = True;
                PreBreakoutFailure = False;
            }
            Commentary("fsDonchianLo="+Text(fsDonchianLo));
            If(Low < fsDonchianLo && TurtleUnits >= 1)
            {
                // 开仓价格取突破下轨-一个价位和最低价之间的较大值，这样能更接近真实情况，并能尽量保证成交
                myEntryPrice = max(low,fsDonchianLo - MinPoint);
                myEntryPrice = IIF(myEntryPrice > Open, Open,myEntryPrice); // 大跳空的时候用开盘价代替
                preEntryPrice = myEntryPrice;
                SellShort(TurtleUnits,myEntryPrice);
                SendOrderThisBar = True;
                PreBreakoutFailure = False;
            }
        }
        If(MarketPosition == 1) // 有多仓的情况
        {
            Commentary("ExitLowestPrice="+Text(ExitLowestPrice));
            If(Low < ExitLowestPrice)//移动止损处理
            {
                myExitPrice = max(Low,ExitLowestPrice - MinPoint);
                myExitPrice = IIF(myExitPrice > Open, Open,myExitPrice); // 大跳空的时候用开盘价代替
                Sell(0,myExitPrice);    // 数量用0的情况下将全部平仓
            }Else
            {
                If(preEntryPrice!=InvalidNumeric && TurtleUnits >= 1)
                {
                    If(Open >= preEntryPrice + 0.5*N && CurrentEntries < nEntries) // 如果开盘就超过设定的1/2N,则直接用开盘价增仓。
                    {
                        myEntryPrice = Open;
                        preEntryPrice = myEntryPrice;
                        Buy(TurtleUnits,myEntryPrice);
                        SendOrderThisBar = True;
                    }
                    while(High >= preEntryPrice + 0.5*N && CurrentEntries < nEntries) // 以最高价为标准，判断能进行几次增仓
                    {
                        myEntryPrice = preEntryPrice + 0.5 * N;
                        preEntryPrice = myEntryPrice;
                        if(False == Buy(TurtleUnits,myEntryPrice))
                        {
                            break;
                        }
                        SendOrderThisBar = True;
                    }
                }
                // 止损指令
                If(Low <= preEntryPrice - 2 * N && SendOrderThisBar == false) // 加仓Bar不止损
                {
                    myExitPrice = preEntryPrice - 2 * N;
                    myExitPrice = IIF(myExitPrice > Open, Open,myExitPrice); // 大跳空的时候用开盘价代替
                    Sell(0,myExitPrice); // 数量用0的情况下将全部平仓
                    PreBreakoutFailure = True;
                }
            }
        }Else If(MarketPosition ==-1) // 有空仓的情况
        {
            // 求出持空仓时离市的条件比较值
            Commentary("ExitHighestPrice="+Text(ExitHighestPrice));
            If(High > ExitHighestPrice)
            {
                myExitPrice = Min(High,ExitHighestPrice + MinPoint);
                myExitPrice = IIF(myExitPrice < Open, Open,myExitPrice); // 大跳空的时候用开盘价代替
                BuyToCover(0,myExitPrice);    // 数量用0的情况下将全部平仓
            }Else
            {
                If(preEntryPrice!=InvalidNumeric && TurtleUnits >= 1)
                {
                    If(Open <= preEntryPrice - 0.5*N && CurrentEntries < nEntries) // 如果开盘就超过设定的1/2N,则直接用开盘价增仓。
                    {
                        myEntryPrice = Open;
                        preEntryPrice = myEntryPrice;
                        SellShort(TurtleUnits,myEntryPrice);
                        SendOrderThisBar = True;
                    }
                    while(Low <= preEntryPrice - 0.5*N && CurrentEntries < nEntries) // 以最低价为标准，判断能进行几次增仓
                    {
                        myEntryPrice = preEntryPrice - 0.5 * N;
                        preEntryPrice = myEntryPrice;
                        if(False == SellShort(TurtleUnits,myEntryPrice))
                        {
                            break;
                        }
                        SendOrderThisBar = True;
                    }
                }
                // 止损指令
                If(High >= preEntryPrice + 2 * N &&SendOrderThisBar==false) // 加仓Bar不止损
                {
                    myExitPrice = preEntryPrice + 2 * N;
                    myExitPrice = IIF(myExitPrice < Open, Open,myExitPrice); // 大跳空的时候用开盘价代替
                    BuyToCover(0,myExitPrice); // 数量用0的情况下将全部平仓
                    PreBreakoutFailure = True;
                }
            }
        }
        Commentary("CurrentEntries = " + Text(CurrentEntries));
        commentary("当前头寸为"+text(CurrentContracts));
        //处理t+0
        //如果是日线，不要在开仓bar上平仓。barssinceentry>=1
        //日线以下，序列变量来保存当日开仓数量和昨日开仓数量。
        //date (truedate)data<>data[1] 当日开仓数量加到昨日开仓数量上去 当日开仓数量清零
        //所有的平仓，都要跟昨日开仓数量进行比较
    } 
//------------------------------------------------------------------------
// 编译版本 GS2010.12.08
// 版权所有    TradeBlazer Software 2003－2025
// 更改声明 TradeBlazer Software保留对TradeBlazer平
//          台每一版本的TradeBlazer公式修改和重写的权利
//------------------------------------------------------------------------