/*
------------------------------------------------------------------------
简称: Test_For_BuySell
名称: 测试BuySell及MarketPosition图表信号执行逻辑
测试品种: rb2210、ag2206
测试周期：1分钟
测试结论：
1、MarketPosition及BuySell属于图表交易模式，在当前Bar为了保证信号不闪烁BuySell必须反复执行来确认图表信号有效，并改变MarketPosition的值
2、MarketPosition为序列变量，其当前Bar初值为前一根Bar的终值
3、除BuySell外的代码如果不想被反复执行，可以通过全局状态变量来进行处理
4、如果BuySell都不想反复执行，那就不能用图表系统，只能用A函数+Global状态变量来解决
------------------------------------------------------------------------
*/
Params
    Numeric fastLength(3);
    Numeric slowLength(5);
    Numeric myPos(1);
Vars
    Global Integer tickCounter(0);        // tick计数器
    Global Integer BuySellCounter(0);    // BuySell在当前Bar运行次数计数器
    Global Integer orderBarIndex;        // BuySell执行Bar的索引值
    Bool ret;
    Bool isOrderBar(False);
    Series<Numeric> fastMA; 
    Series<Numeric> slowMA;
    Series<Numeric> a_EntryPrice;
    Series<Numeric> a_EntryPos;
    Series<Numeric> a_ExitPrice;

Events
    OnInit()
    {
         orderBarIndex = InvalidInteger ;
    }
    
    OnBar(ArrayRef<Integer> indexs)
    {
        Print("[ tickCounter: " + Text(tickCounter) + " ]");
        If(orderBarIndex != CurrentBar) BuySellCounter = 0;
        //Print("[" + Text(tickCounter) + "]orderBarIndex = " + Text(orderBarIndex));
        fastMA = AverageFC(Close[1],fastLength);
        slowMA = AverageFC(Close[1],slowLength);
        // 开仓
        If(MarketPosition == 0)
        {
            If(Open > fastMA && fastMA > slowMA)
            {
                a_EntryPrice = Open;
                a_EntryPos = myPos;
                ret = Buy(a_EntryPos, a_EntryPrice);    // 通过每次执行BuySell发送图表信号，从而改变MarketPosition的值
                If(ret)
                {
                    orderBarIndex = CurrentBar;                // 记录BuySell当前Bar的索引值
                    BuySellCounter = BuySellCounter + 1;    // 每执行一次BuySell计数器+1
                    Print("[Buy]MarketPosition = " + Text(MarketPosition));
                    Print("BuySellCounter = " + Text(BuySellCounter));
                    If(BuySellCounter==1)
                    {
                        // 这里放不想被反复执行的部分代码，例如写入log
                        Print("这段代码当前Bar只会执行一次!");
                    }
                }
            }
            If(Open < fastMA && fastMA < slowMA)
            {
                a_EntryPrice = Open;
                a_EntryPos = myPos;
                ret = SellShort(a_EntryPos, a_EntryPrice);
                If(ret)
                {
                    orderBarIndex = CurrentBar;
                    BuySellCounter = BuySellCounter + 1;
                    Print("[SellShort]MarketPosition = " + Text(MarketPosition));
                    Print("BuySellCounter = " + Text(BuySellCounter));
                    If(BuySellCounter==1)
                    {
                        // 这里放不想被反复执行的部分代码，例如写入log
                        Print("这段代码当前Bar只会执行一次!");
                    }
                }
            }
        }
        // 处理多头持仓
        If(MarketPosition == 1 && !isOrderBar)
        {
            If(fastMA < slowMA)
            {
                a_ExitPrice = Open ;
                ret = Sell(a_EntryPos, a_ExitPrice);
                If(ret)
                {
                    orderBarIndex = CurrentBar;
                    BuySellCounter = BuySellCounter + 1;
                    Print("[Sell]MarketPosition = " + Text(MarketPosition));
                    Print("BuySellCounter = " + Text(BuySellCounter));
                    If(BuySellCounter==1)
                    {
                        // 这里放不想被反复执行的部分代码，例如写入log
                        Print("这段代码当前Bar只会执行一次!");
                    }
                }
            }
        }
        // 处理空头持仓
        If(MarketPosition == -1 && !isOrderBar)
        {
            If(fastMA > slowMA)
            {
                a_ExitPrice = Open ;
                ret = BuyToCover(a_EntryPos, a_ExitPrice);
                If(ret)
                {
                    orderBarIndex = CurrentBar;
                    BuySellCounter = BuySellCounter + 1;
                    Print("[BuyToCover]MarketPosition = " + Text(MarketPosition));
                    Print("BuySellCounter = " + Text(BuySellCounter));
                    If(BuySellCounter==1)
                    {
                        // 这里放不想被反复执行的部分代码，例如写入log
                        Print("这段代码当前Bar只会执行一次!");
                    }
                }
            }
        }
        // 图表均线
        PlotNumeric("fastMA", fastMA, fastMA, White);
        PlotNumeric("slowMA", slowMA, slowMA, Yellow);
        // 计数器
        tickCounter = tickCounter + 1;
    }